tdevropa-test

Install/Upgrade: Adobe ETLA Creative Cloud: Master Collection (32-bit) - Windows x32 TEMPLATE
Log In or Register to download the BES file, and more.

0 Votes

Description

About Master Collection

Adobe Creative Cloud Master Collection is a set of programs developed by Adobe Systems.

Licensing

This Adobe software is made available through an enterprise term license agreement.

Use of this software is not free.

About This Task

This task will install/upgrade: Adobe Master Collection

This task is applicable on: Windows x32

Important Notes

  • Adobe Update Manager is disabled. Updates to this application must be installed through the Adobe Remote Update Manager.

Property Details

ID3856
StatusBeta - Preliminary testing ready for more
TitleInstall/Upgrade: Adobe ETLA Creative Cloud: Master Collection (32-bit) - Windows x32 TEMPLATE
DomainBESC
CategorySoftware Sharing
Download Size9000000000
SourceInternal
Source IDjgstew
Source Release Date9/10/2014 12:00:00 AM
Added by on 9/12/2014 12:52:20 PM
Last Modified by on 9/12/2014 12:52:20 PM
Counters 2497 Views / 1 Download
User Rating 1 star 2 star 3 star 4 star 5 star * Average over 0 ratings. ** Log In or Register to add your rating.

Relevance

Windows XP or Later (Relevance 2997025)
Used in 6264 fixlets and 5 analyses * Results in a true/false
Show indented relevance
/* Windows XP or later */ version of operating system >= "5.1"
Windows Only (Relevance 2997197)
Used in 6448 fixlets and 32 analyses * Results in a true/false
Show indented relevance
/* Windows Only */ windows of operating system
Used in 1 fixlet * Results in a true/false
Show indented relevance
not x64 of operating system
Used in 2 fixlets * Results in a true/false
Show indented relevance
/* Adobe Acrobat must be installed before CC apps */ exists keys whose (value "DisplayName" of it as string contains "Adobe Acrobat" AND (it >= "11.0.08" as version) of (value "DisplayVersion" of it as string as version)) of keys "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" of (native registry;registry)
Used in 2 fixlets * Results in a true/false
Show indented relevance
( not exists keys whose (value "DisplayName" of it as string starts with "AdobeCC_Full" AND (it >= "1.2.0000" as version) of (value "DisplayVersion" of it as string as version)) of keys "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" of (native registry;registry) )

Actions

Action 1 (default)

Action Link Click here to deploy this action.
Script Type tdevropa-test Action Script
// -- DOWNLOADS -----------------------

// - This is the commandline 7zip console which is use to unpack installers
// - https://virustotal.com/en/file/2a3afe19c180f8373fa02ff00254d5394fec0349f5804e0ad2f6067854ff28ac/analysis
prefetch 7za920.zip sha1:9ce9ce89ebc070fea5d679936f21f9dde25faae0 size:384846 http://softlayer-dal.dl.sourceforge.net/project/sevenzip/7-Zip/9.20/7za920.zip

// - This unzip is a compiled verion of unzip v5.52 fom http://info-zip.org/
// - https://virustotal.com/en/file/8d9b5190aace52a1db1ac73a65ee9999c329157c8e88f61a772433323d6b7a4a/analysis
prefetch unzip.exe sha1:e1652b058195db3f5f754b7ab430652ae04a50b8 size:167936 http://software.bigfix.com/download/redist/unzip-5.52.exe

// Adobe CC Product build - This is the output of the the Adobe Cloud Packager
prefetch AdobeCC_AppBuild.zip sha1:000000 size:9000000000 http://MANUAL_CREATION_AND_CACHING_REQUIRED/AdobeCC_AppBuild_Full_x32.zip

// -- END:DOWNLOADS -----------------------

// Add unzip.exe & 7za920.zip to the client utility cache since they are used in many tasks
// - This will prevent these from from being redownloaded multiple times to the client ( as long as they are in either the download or utility cache )
utility __Download\unzip.exe
utility __Download\7za920.zip


// EXTRACT using unzip: the 7zip command line utility
waithidden __Download\unzip.exe -o "{pathname of file "7za920.zip" of folder "__Download" of client folder of current site}" -d "{pathname of folder "__Download" of client folder of current site}"


// DELETE the InstallAdobe temp folder incase it exists and has something in it
folder delete "{pathname of folder "temp" of windows folder}\InstallAdobe"
// CREATE the InstallAdobe temp folder to unpack the installers and run
folder create "{pathname of folder "temp" of windows folder}\InstallAdobe"


// EXTRACT using 7zip: the Adobe package build files into Windows Temp
waithidden "{(pathname of file "7za.exe" of folder "__Download" of client folder of current site)}" x -r -y -o"{pathname of folder "InstallAdobe" of folder "temp" of windows folder}" "{pathname of file "AdobeCC_AppBuild.zip" of folder "__Download" of client folder of current site}"
// unzip fails on this large zip file.
//waithidden __Download\unzip.exe -o "{pathname of file "AdobeCC_AppBuild.zip" of folder "__Download" of client folder of current site}" -d "{pathname of folder "InstallAdobe" of folder "temp" of windows folder}"


// INSTALL program
waithidden "{pathname of system folder & "\msiexec.exe"}" /i "{ pathname of file whose(name of it as lowercase ends with ".msi") of folder "InstallAdobe" of folder "temp" of windows folder }" /qn /norestart /L* "{(pathname of parent folder of client) & "\__BESData\__Global\Logs\Install_AdobeCC" & "_" & ((year of it as string & month of it as two digits & day_of_month of it as two digits) of date (local time zone) of now & "-" & (two digit hour of it & two digit minute of it & two digit second of it) of time (local time zone) of now) & ".log"}"
// INSTALL Exceptions (after main MSI install)
if{ exists files "ExceptionDeployer.exe" of folders "Exceptions" of folders "InstallAdobe" of folders "temp" of windows folder }
waithidden "{ pathname of file "ExceptionDeployer.exe" of folder "Exceptions" of folder "InstallAdobe" of folder "temp" of windows folder }" --workflow=install --mode=post
endif


// DELETE: Desktop Shortcuts
if{ exists (files whose( (name of it as lowercase ends with ".lnk") AND (exists shortcut whose(pathname of it as lowercase contains "adobe") of it) AND ( (creation time of it - active start time of active action) > 0*minute ) ) of folders "C:\Users\Public\Desktop") }

delete __createfile
delete deleteAdobeShortcuts.bat

// CREATEFILE - make a batch file to delete all created desktop shortcuts
// http://ss64.com/nt/del.html
// https://support.bigfix.com/inspectors/Action%20Objects_Win.html#action
createfile until END_OF_FILE
{ concatenation "%0d%0a" of (("DEL /Q %22" & it & "%22") of pathnames of files whose( (name of it as lowercase ends with ".lnk") AND (exists shortcut whose(pathname of it as lowercase contains "adobe") of it) AND ( (creation time of it - active start time of active action) > 0*minute ) ) of folders "C:\Users\Public\Desktop") }
END_OF_FILE

move __createfile deleteAdobeShortcuts.bat
waithidden cmd.exe /C deleteAdobeShortcuts.bat > "{(pathname of folder "__BESData\__Global\Logs" of parent folder of client)}\install_deleteAdobeShortcuts.bat.log"

endif
// END of DELETE: Desktop Shortcuts


// DELETE: CLEANUP the InstallAdobe temp folder
folder delete "{pathname of folder "temp" of windows folder}\InstallAdobe"


// UPDATE: Install any missing updates
if{(exists files "Common Files\Adobe\OOBE_Enterprise\RemoteUpdateManager\RemoteUpdateManager.exe" of folders whose(name of it as lowercase starts with "program files") of root folder of drive of system folder) AND (exists files "Common Files\Adobe\OOBE\PDApp\UWA\UpdaterCore.dll" of folders whose(name of it as lowercase starts with "program files") of root folder of drive of system folder)}
waithidden "{pathname of file "Common Files\Adobe\OOBE_Enterprise\RemoteUpdateManager\RemoteUpdateManager.exe" of folders whose(name of it as lowercase starts with "program files") of root folder of drive of system folder}"
endif
Success Criteria

This action will be considered successful when the applicability relevance evaluates to false.



Comments

Log In or Register to leave comments!

Recommended Articles

drivers for dell optiplex 7010 how to fully uninstall java ssms 2012 download add computer to domain powershell how to uninstall gimp on mac ibm acquires bigfix cyberpower personal edition flash player java cisco anyconnect secure mobility client windows 8 download dotfuscator software services how to uninstall teamviewer oracle xml publisher desktop dell controlvault software